Displays LCD são itens indispensáveis para quem mexe com Arduíno. São componentes relativamente baratos e oferecem, dependendo do uso, uma forma mais eficaz do que o serial monitor para acompanhamento de dados. Neste post você verá que o uso de um display gráfico LCD 128×64 com Arduino levanta possibilidades de configuração interessantes para o seu projeto.
Já utilizei displays LCD em muitos artigos aqui no Arduino e Cia, seja mostrando indicadores de temperatura e umidade em um LCD Nokia 5110, ou as distâncias lidas por um sensor ultrasônico, em um LCD 16×2.
O display gráfico LCD 128×64
Vou mostrar para vocês um outro display LCD gráfico, este com resolução de 128×64 pixels, baseado no chip ST7920.
Este display tem backlight azul e escrita branca, e com ele (e a biblioteca certa) você consegue efeitos gráficos muito legais como rotação de tela, mudança de fontes de texto, rotação de texto e, claro, desenhar. Publiquei um pequeno vídeo no Youtube mostrando algumas dessas funções:
O display tem 20 pinos, numerados da direita para a esquerda, conforme podemos ver na foto abaixo. Ele pode ser utilizado para se comunicar com o Arduino tanto de forma serial como paralela. Neste artigo, onde a velocidade de atualização do LCD não é um ponto crítico, vamos utilizar a comunicação serial, ocupando apenas 4 portas do Arduino:
Informações mais detalhadas sobre a pinagem do LCD podem ser encontradas no datasheet do produto.
Atualizado: Veja como ligar este display em modo paralelo no artigo Display gráfico LCD 128×64 ST7920 em modo 8 bits.
Atualizado: Monte um relógio analógico/digital com esse display. Veja no post Relógio com Display LCD 128×64 e módulo RTC DS3231.
Circuito display 128×64 com Arduino
O circuito usa um potenciômetro (utilizei um de 50K) para regulagem do contraste do display, e a alimentação é feita pelos 5v do Arduino. Para alimentar o backlight, eu usei os 3.3v do Arduino Uno R3 (mas segundo as especificações, também pode ser ligado em 5v):
Abaixo temos uma tabela com as funções dos pinos desse display:
A biblioteca que vamos usar é a U8glib , uma biblioteca bem completa (e complexa, às vezes), com muitos exemplos de utilização. Recomendo uma visita à página da u8glib (em inglês) , onde você vai encontrar instruções sobre o funcionamento da biblioteca e também informações detalhadas sobre a utilização de cada comando. Vale a pena explorar.
Para instalar a biblioteca U8glib, acesse o menu Sketch -> Incluir Biblioteca -> Gerenciar Bibliotecas. Dentro do Gerenciador de Bibliotecas procure por “u8glib”, instalando a U8glib by oliver, conforme imagem abaixo:
Dúvidas na instalação da biblioteca? Confira o post Como instalar uma biblioteca na IDE Arduino.
Com a biblioteca instalada, vamos ao programa, que é baseado no exemplo “GraphicsTest” e que já vem com a biblioteca. Conforme as instruções do desenvolvedor, conservei o cabeçalho com as informações de direitos autorais:
/*
GraphicsTest.pde
>>> Before compiling: Please remove comment from the constructor of the
>>> connected graphics display (see below).
Universal 8bit Graphics Library, http://code.google.com/p/u8glib/
Copyright (c) 2012, olikraus@gmail.com
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions
are met:
* Redistributions of source code must retain the above copyright notice,
this list of conditions and the following disclaimer.
* Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in the
documentation and/or other materials provided with the distribution.
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND
CONTRIBUTORS "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES,
INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR
CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/
#include "U8glib.h"
// A linha abaixo define as ligacoes e deve ser
// ajustada conforme o display utilizado.
U8GLIB_ST7920_128X64_1X u8g(6, 5, 4 ,7); //Enable, RW, RS, RESET
int display = 1;
void u8g_prepare()
{
u8g.setFont(u8g_font_6x10);
u8g.setFontRefHeightExtendedText();
u8g.setDefaultForegroundColor();
u8g.setFontPosTop();
}
void u8g_Tela1() //Tela 1 - Arduino e Cia - Retangulos
{
u8g.setFont(u8g_font_unifont);
u8g.drawStr( 11, 35, "Arduino e Cia");
u8g.drawStr( 12, 35, "Arduino e Cia");
u8g.drawFrame(0,0,128,64);
u8g.drawFrame(2,2,124,60);
}
void u8g_Tela2() //Tela 2 - Moldura e relógio
{
u8g.drawRFrame(0,0,128,64,3);
u8g.drawStr( 3, 10, "Hor.: 13:00");
u8g.drawStr( 3, 25, "Temp: 27");
char s[2] = " ";
s[0] = 176;
u8g.drawStr(51, 25, s);
u8g.drawStr( 3, 40, "Umid: 25%");
u8g.drawCircle(95,32,28);
u8g.drawCircle(95,32,29);
u8g.drawLine(95, 9, 95, 4);
u8g.drawLine(123, 32, 118, 32);
u8g.drawLine(95, 55, 95, 60);
u8g.drawLine(67, 32, 72, 32);
u8g.drawLine(95, 32, 95, 12);
u8g.drawLine(95, 32, 100.8, 21.87 );
u8g.setFont(u8g_font_04b_03);
u8g.drawStr(89,43, "Tag");
u8g.drawStr(85,50, "Heuer");
}
void u8g_Tela3() //Tela 3 - Caracteres Ascii - Pag. 1
{
char s[2] = " ";
u8g.drawStr( 0, 0, "ASCII page 1");
for(int y = 0; y < 6; y++ )
{
for(int x = 0; x < 16; x++ )
{
s[0] = y*16 + x + 32;
u8g.drawStr(x*7, y*10+10, s);
}
}
}
void u8g_Tela4() //Tela 3 - Caracteres Ascii - Pag. 2
{
char s[2] = " ";
uint8_t x, y;
u8g.drawStr( 0, 0, "ASCII page 2");
for( y = 0; y < 6; y++ )
{
for( x = 0; x < 16; x++ )
{
s[0] = y*16 + x + 160;
u8g.drawStr(x*7, y*10+10, s);
}
}
}
void u8g_Tela5() //Tela 5 - Arduino e Cia - Retangulo preenchido
{
u8g.setFont(u8g_font_unifont);
u8g.drawBox(0,0,128,64);
u8g.drawBox(2,2,124,60);
u8g.setColorIndex(0);
u8g.drawStr( 11, 35, "Arduino e Cia");
u8g.drawStr( 12, 35, "Arduino e Cia");
u8g.drawFrame(2,2,124,60);
}
void u8g_Tela6() //Tela 6 - Arduino e Cia em 0, 90 e 270 graus
{
u8g.setFont(u8g_font_helvB08);
u8g.drawStr(50,31, " Arduino");
u8g.drawStr90(50,31, " e");
u8g.drawStr270(50,31, " Cia");
}
void u8g_Tela7() //Tela 7 - Fontes diferentes
{
u8g.setFont(u8g_font_robot_de_niro);
u8g.drawStr(5,13, "Arduino e Cia !");
u8g.setFont(u8g_font_helvB08);
u8g.drawStr(5,25, "Arduino e Cia !");
u8g.drawBox(5,31, 118,11);
u8g.setColorIndex(0);
u8g.setFont(u8g_font_8x13);
u8g.drawStr(5,41, "Arduino e Cia !");
u8g.setColorIndex(1);
u8g.setFont(u8g_font_ncenB10);
u8g.drawStr(5,60, "Arduino e Cia !");
}
void draw() //Rotina Desenho
{
u8g_prepare();
switch(display) //Carrega a tela correspondente
{
case 1:
u8g_Tela1();
break;
case 2:
u8g_Tela2();
break;
case 3:
u8g_Tela3();
break;
case 4:
u8g_Tela4();
break;
case 5:
u8g_Tela5();
break;
case 6:
u8g_Tela6();
break;
case 7:
u8g_Tela7();
break;
}
}
void setup()
{
// flip screen, if required
//u8g.setRot180();
// assign default color value
if ( u8g.getMode() == U8G_MODE_R3G3B2 )
u8g.setColorIndex(255); // white
else if ( u8g.getMode() == U8G_MODE_GRAY2BIT )
u8g.setColorIndex(1); // max intensity
else if ( u8g.getMode() == U8G_MODE_BW )
u8g.setColorIndex(1); // pixel on
//u8g.setContrast(0x30);
}
void loop()
{
// picture loop
for (display =1; display < 8; display++) //Carrega as telas de 1 a 7
{
u8g.firstPage();
do
{
draw();
}
while( u8g.nextPage() );
delay(3000); //Pausa de 3 segundos e reinicia o processo
}
}Um último detalhe sobre esta biblioteca é que ela suporta vários tipos de displays e controladores, bastando para isso mudar os parâmetros de comunicação dentro do programa. Para uma lista completa dos dispositivos suportados e respectiva configuração, acesse este link.
Gostou do post sobre display gráfico LCD 128×64 com Arduino? Então confira outros posts sobre displays aqui mesmo no Arduino e Cia!